*This versions receives the profiling macro name as its first argument;
* and gives an iteration counter;
%MACRO Plkhci(macroname,lower,upper,max,side,tol=0.000001,alpha=0.05);
  %LET ProfileIteration=0;
  %DO %WHILE (%SYSEVALF(&upper-&lower>&tol));
    %LET profilepar=%SYSEVALF(0.5*(&lower+&upper));
	%LET ProfileIteration=%EVAL(&ProfileIteration+1);
	%PUT At iteration &ProfileIteration: profile parameter=&profilepar;
	ODS OUTPUT FitStatistics=FitStatistics;
    %&macroname(&profilepar);
    DATA _temp_;
	  SET FitStatistics;
      IF _N_=1;
      target=%SYSEVALF(&max)-CINV(1-&alpha,1)/2;
      LogL=-Value/2;
	  profilepar=%SYSEVALF(&profilepar);
      IF ((&side="L" AND LogL>target)OR(&side="R" AND LogL<target)) THEN
          CALL SYMPUT("upper",profilepar);
        ELSE
          CALL SYMPUT("lower",profilepar);
    RUN;
  %END;
  %PUT Accuracy of &tol achieved;
  %IF (&side="L") %THEN %DO;
	%PUT Left-sided %SYSEVALF(100*(1-&alpha))% LR CI bound is &profilepar; %END;
  %IF (&side="R") %THEN %DO;
	%PUT Right-sided %SYSEVALF(100*(1-&alpha))% LR CI bound is &profilepar; %END;
%MEND;

/*Check it out;
DATA binomial; y=10; n=100; RUN;

%MACRO BinomialProfile(p);
  PROC NLMIXED DF=1E6 DATA=Binomial TECH=NONE;
    MODEL y~BINOMIAL(n,&p);
  RUN;
%MEND;
%Plkhci(BinomialProfile,0.0,0.1,-2.0259739,side="L");
%Plkhci(BinomialProfile,0.1,0.9,-2.0259739,side="R");
*/